Membuat Status Loading Data Dengan FetchProgress ADO VB6

Berikut ini adalah cara memebuat status loading data dengan FetchProgress ADO di visual basic 6, untuk mempraktekannya siapkan :

1. Buat 1 Project baru dengan 1 Form.
2. Tambahkan 1 DataGrid, 1 Commandbutton, 1 Label, dan 1 Progressbar. Progressbar dapat Anda ambil dari Add Component: Microsoft Windows Common Controls 5.0 (SP2).
3. Tambahkan reference Microsoft ActiveX Data Objects 2.0  Library dari menu Project->References...
4. Copy-kan coding berikut ke dalam editor form yang bertalian.

          Option Explicit 'Setiap variabel yg digunakan harus dideklarasikan
          'Karena dipakai di beberapa prosedur, deklarasikan di atas
          Private WithEvents objRst As ADODB.Recordset
          Private rsTotal As ADODB.Recordset
          Private maks As Integer


          Private Sub Command1_Click()
              Dim strConn As String
              Dim strSQL  As String
              'Karena proses ini memakan waktu, ganti pointer

              'mouse menjadi bentuk Hourglass (jam pasir)
              Screen.MousePointer = vbHourglass
              DoEvents
              'Sesuaikan lokasi database di PC Anda

              strConn = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
                        "Data Source=" & App.Path & "\mahasiswa.mdb;" & _
                        "Persist Security Info=False"
              'Buat recordset baru untuk menampung jumlah record
              Set rsTotal = New ADODB.Recordset

              rsTotal.CursorLocation = adUseClient
              rsTotal.Open "SELECT COUNT('NIM') AS Jlh FROM t_mhs", strConn
              'Tampung jumlah record seluruhnya dari rsTotal
              maks = Val(rsTotal.Fields(0))

              'Ambil data dari tabel t_mhs
              strSQL = "SELECT * FROM t_mhs"
              'Buat recordset baru untuk melihat proses kemajuan
              Set objRst = New ADODB.Recordset

              objRst.CursorLocation = adUseClient
              objRst.Properties("Initial Fetch Size") = 0
              objRst.Properties("Background Fetch Size") = 1
              DoEvents
              'Inisialisasi jumlah record ke progressbar

              ProgressBar1.Max = maks
              ProgressBar1.Value = 0
              'Buka tabel... di sini mulai proses pengambilan...
              objRst.Open strSQL, strConn, adOpenKeyset, adLockOptimistic, adAsyncFetch

              DoEvents
          End Sub

          Private Sub objRst_FetchProgress(ByVal Progress As Long, _

                                           ByVal MaxProgress As Long, _
                                           adStatus As ADODB.EventStatusEnum, _
                                           ByVal pRecordset As ADODB.Recordset)
              Me.Caption = Progress  'Tampilkan kemajuan di judul atas form
              ProgressBar1.Value = Progress

              'Tampilkan persentase kemajuan di Label1
              Label1.Caption = Format((Progress / maks) * 100, "###") & "%"
              'Jika seluruh record sudah berhasil diambil...
              If ProgressBar1.Value = MaxProgress Then

                 'Tampilkan ke DataGrid
                 ProgressBar1.Value = 0
                 Label1.Caption = ""
                 Set DataGrid1.DataSource = objRst

                 'Normalkan pointer Mouse kembali
                 Screen.MousePointer = vbDefault
              End If
          End Sub

Tags:

contoh program vb6, contoh fungsi di vb6, cara penggunaan fungsi vb, tutorial vb6, download tutorial vb6, vb6 tutorial download, dasar dasar vb6, belajar vb6, cara mudah belajar vb6, vb6 artikel download, vb6 blog, contoh program vb6, artikel vb6, semua tentang vb6, vb6 api, cara menggunakan module, cara menggunakan class module